玄坛寄售

[@main]
#IF
CHECKVAR GLOBAL 玄坛使者 = 开放模式
#SAY
元宝寄售由我来全权负责，不管你是商界名流还是来做点小本\
生意，只要是诚心来做生意的顾客就是我的上帝，我愿给你提\
供最周全的服务。\\
<Color=green 我想对><王城捐献/@王城捐献>\
<寄售元宝/@寄售元宝>　　　　　　　　　<购买元宝/@购买元宝>\
<取消寄售/@取消寄售>　　　　　　　　　<查询元宝/@查询元宝>\
<领取金币/@领取金币>\\
<离开/@exit>
#ELSESAY
当前该功能没有开放，敬请关注！\\ 

<离开/@exit>
[@王城捐献]
修罗入侵愈烈，国家连年征战，国库亏空。\ 
国王诏令天下，征集民间财物纳入国库，以备军需。\ 
我奉王令，再此收缴金币，金条，金砖等物上交国库。\ 
作为对交纳财物最多的勇士，每周国王将会给予其 <Color=green 本体>\
<Color=green 强化技能书>的奖励！\
\
<了解详情/@_BanBen_jieshao>\
<我来交纳金币/@_BanBen_beginjinbi> <我来交纳金条金砖/@_BanBen_jinzhuan>\
<我是上周的冠军，我来领奖/@_BanBen_getjiangl> <查询本周排名/@_BanBen_viewPH>\
<离开/@exit>\
[@_BanBen_jieshao]
截至每周四凌晨0：00，交纳财物最多的勇士将成为冠\ 
军，在未来一周内（下周四0：00之前）可以在我这里领取\
本职业本体强化技能书一本，超过时间将无法领取。\
同时该勇士交纳的金币将存入国库，金币数将清零。清\ 
零后可以继续交纳进入下一周的排行榜中。\
其他勇士的金币数目将继续保留，计入下周排行榜。\
<我来交纳金币/@_BanBen_beginjinbi> <我来交纳金条金砖/@_BanBen_jinzhuan>\
<我是上周的冠军，我来领奖/@_BanBen_getjiangl> <查询本周排名/@_BanBen_viewPH>\
<离开/@exit>\
[@_BanBen_getjiangl]
#IF
checknamelist ..\QuestDiary\数据文件\王城捐献.txt
#ACT
delnamelist ..\QuestDiary\数据文件\王城捐献.txt
goto @技能奖励
#SAY
为表扬你对国家做出的贡献，这本强化技能书就送给你吧！\
\
<谢谢/@exit>
#ELSESAY
您不是上周本服第一名，请回吧。\ 
\
<离开/@exit>\
[@技能奖励]
#IF
checkjob warrior
#ACT
give 本体强化攻杀1 1
break
#IF
checkjob wizard
#ACT
give 本体强化火球1 1
break
#IF
checkjob taoist
#ACT
give 本体强化施毒1 1
break
[@_BanBen_viewPH]
#ACT
mov S10
mov S11
mov S12
mov S13
mov S14
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\王城捐献.txt S0 0
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S0 S1
FORMATSTR S10 %-9s%-18s%s\ 第1名|<$STR(S0)>|<$STR(S1)>
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\王城捐献.txt S0 1
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S0 S1
FORMATSTR S11 %-9s%-18s%s\ 第2名|<$STR(S0)>|<$STR(S1)>
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\王城捐献.txt S0 2
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S0 S1
FORMATSTR S12 %-9s%-18s%s\ 第3名|<$STR(S0)>|<$STR(S1)>
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\王城捐献.txt S0 3
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S0 S1
FORMATSTR S13 %-9s%-18s%s\ 第4名|<$STR(S0)>|<$STR(S1)>
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\王城捐献.txt S0 4
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S0 S1
FORMATSTR S14 %-9s%-18s%s\ 第5名|<$STR(S0)>|<$STR(S1)>
#IF
#SAY
<Color=Green 上交金币排名>\
<Color=Green 名次 姓名 金币数量(以万为单位)>\
<$STR(S10)>
<$STR(S11)>
<$STR(S12)>
<$STR(S13)>
<$STR(S14)>
\
<离开/@exit>\
[@_BanBen_beginjinbi]
#ACT
QUERYVAL 0 1 3 @交纳金币 请输入你要上缴的金币数(以万为单位)
[@交纳金币]
#IF
random 1
#ACT
mov P0 $STR(M0)
MULT P0 10000
#IF
checkgold $STR(P0)
#ACT
take 金币 $STR(P0)
Calcvar HUMAN 王城捐献金币 + $STR(M0)
mov P0
goto @王城捐献排行
#SAY
国家已经受到你上交的金币，你现在上交的总数目为：\ 
{Color=Green <$HUMAN(王城捐献金币)>}万,\
作为对交纳财物最多的勇士，每周国王将会给予其 <Color=green 本体>\
<Color=green 强化技能书>的奖励！\
\
<离开/@exit>\
#ELSESAY
你的包裹中没有这么多金币。\ 
\
<算了/@exit>\
[@_BanBen_jinzhuan]
#IF
checkitem 金条 1
#ACT
take 金条 1
Calcvar HUMAN 王城捐献金币 + 100
mov P0
goto @王城捐献排行
break
#SAY
国家已经受到你上交的金条，你现在上交的总数目为：\ 
{Color=Green <$HUMAN(王城捐献金币)>}万,\
作为对交纳财物最多的勇士，每周国王将会给予其 <Color=green 本体>\
<Color=green 强化技能书>的奖励！\
\
<离开/@exit>\
#IF
checkitem 金砖 1
#ACT
take 金砖 1
Calcvar HUMAN 王城捐献金币 + 500
mov P0
goto @王城捐献排行
break
#SAY
国家已经受到你上交的金砖，你现在上交的总数目为：\ 
{Color=Green <$HUMAN(王城捐献金币)>}万,\
作为对交纳财物最多的勇士，每周国王将会给予其 <Color=green 本体>\
<Color=green 强化技能书>的奖励！\
\
<离开/@exit>\
#ELSESAY
你的包裹中没有金砖或金条。\ 
\
\
<离开/@exit>\
[@王城捐献排行]
#IF
PosInList $USERNAME ..\QuestDiary\无限排行\王城捐献.txt S0
#ACT
DELVARLIST $STR(S0) ..\QuestDiary\无限排行\王城捐献.txt
#IF
large P0 5
#ACT
break
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\王城捐献.txt S0 $STR(P0)
mov P1
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S0 P1
#IF
CHECKVAR HUMAN 王城捐献金币 > $STR(P1)
#ACT
FORMATSTR S0 %s|%s <$USERNAME>|<$HUMAN(王城捐献金币)>
INSERTVARLIST $STR(P0) $STR(S0) ..\QuestDiary\无限排行\王城捐献.txt
#ELSEACT
inc P0 1
goto @王城捐献排行
[@领取金币]
#IF
CHECKVAR HUMAN 寄售领取金币 > 0
#SAY
欢迎回来，亲爱的顾客。\
请先确认以下内容，然后把属于你的金币领走。\
领取奖品之前请先确认你的金币是否达到了\
上限\
\
<领取金币/@give>\
<取消/@exit>
#ELSESAY
对不起，你无法领取奖品，请确认下列可能：\
1、你并没有寄售元宝！\
2、你寄售的元宝并未售出\
3、你已经领取过金币了\
<确认/@exit>
[@give]
#IF
!CHECKBAGSIZE 1
#SAY
您的包裹空间不足，请整理以后再来\
<离开/@exit>
#ACT
break
#IF
CHECKVAR HUMAN 寄售领取金币 > 4999999
CHECKBAGSIZE 1
#ACT
give 金砖 1
CalcVar Human 寄售领取金币 - 5000000
SaveVar HUMAN 寄售领取金币 ..\QuestDiary\数据文件\玄坛数据.txt
#ACT
break
#SAY
你领取了1个金砖！\
还剩<$Human(寄售领取金币)>金币未领取\
请将包裹保留1格以上空位后再来领取。\
<离开/@exit>
#IF
CHECKVAR HUMAN 寄售领取金币 > 999999
#ACT
GIVE 金条 1
CalcVar Human 寄售领取金币 - 1000000
SaveVar HUMAN 寄售领取金币 ..\QuestDiary\数据文件\玄坛数据.txt
Break
#SAY
你领取了1个金条！\
还剩<$Human(领取金币)>金币未领取\
请将包裹保留10格以上空位后再来领取。\
<离开/@exit>
#IF
CHECKVAR HUMAN 寄售领取金币 > 0
#ACT
mov P0 $GOLDCOUNT
inc P0 $Human(寄售领取金币)
#IF
small P0 5000000
#ACT
give 金币 $Human(寄售领取金币)
Calcvar HUMAN 寄售领取金币 = 0
SAVEVAR HUMAN 寄售领取金币 ..\QuestDiary\数据文件\玄坛数据.txt
#SAY
恭喜你成功领取金币！\
<离开/@exit>
#ELSESAY
你无法再携带更多的金币
[@购买元宝]
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S0 0
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
GETVALIDSTR $STR(S2) | S3 S10
inc S10 \
#ELSEACT
mov S10
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S0 1
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
GETVALIDSTR $STR(S2) | S3 S11
inc S11 \
#ELSEACT
mov S11
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S0 2
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
GETVALIDSTR $STR(S2) | S3 S12
inc S12 \
#ELSEACT
mov S12
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S0 3
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
GETVALIDSTR $STR(S2) | S3 S13
inc S13 \
#ELSEACT
mov S13
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S0 4
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
GETVALIDSTR $STR(S2) | S3 S14
inc S14 \
#ELSEACT
mov S14
#IF
#SAY
目前寄售元宝价格最优惠的商家信息：\
玩家姓名 元宝数量 单价\
<$STR(S10)>
<$STR(S11)>
<$STR(S12)>
<$STR(S13)>
<$STR(S14)>
<离开/@exit>
[@YuanBaoBuy2]
#ACT
mov S0 $SCRIPTPARAM(1)
QUERYVAL 0 1 3 @购买元宝数 请输入你要购买的元宝数量：
[@购买元宝数]
#IF
equal $USERNAME $STR(S0)
#ACT
break
#SAY
系统正忙，请再次尝试！\
\
<离开/@exit>
#IF
small M0 1
#ACT
break
#SAY
输入的元宝数量不正确，请重新输入。\
\
<离开/@exit>
#IF
large M0 200
#ACT
break
#SAY
输入的元宝数量不能大于200，请重新输入。\
\
<离开/@exit>
#IF
PosInList $STR(S0) ..\QuestDiary\无限排行\玄坛数据.txt S1
#ACT
GETVALIDSTR $STR(S1) | P0 S2
GETVALIDSTR $STR(S2) | P1 S3
#IF
large M0 $STR(P0)
#ACT
break
#SAY
寄售的元宝数量不足或者已经售出，请重新刷新（<刷新/@购买元宝>）购买。\
\
<离开/@exit>
#IF
random 1
#ACT
MOV P2 $STR(M0)
MULT P2 $STR(P1)
#IF
!checkgold $STR(P2)
#ACT
break
#SAY
你似乎没有那么多钱啊，还是先少买点元宝吧！\
\
<返回/@YuanBaoBuy>
#IF
checkgold $STR(P2)
#ACT
take 金币 $STR(P2)
GAMEGOLD + $STR(M0)
SENDMSG 0 恭喜<$STR(S0)>的元宝已经以<$STR(P1)>的单价成功售出
DELVARLIST $STR(S1) ..\QuestDiary\无限排行\玄坛数据.txt
MOV P3 $STR(P1)
MULT P1 $STR(M0)
SaveExVar $STR(P1) $STR(S0) 寄售领取金币 ..\QuestDiary\数据文件\玄坛数据.txt
$STR(S0).LOADVAR HUMAN 寄售领取金币 ..\QuestDiary\数据文件\玄坛数据.txt
#SAY
恭喜你已经成功购买了<$STR(M0)>个元宝！\
\
<离开/@exit>
#IF
!CheckOnline $STR(S0)
#ACT
FORMATSTR S1 %s#32%s 你的<$STR(M0)>个元宝在<$DATE.YEAR>-<$DATE.MONTH>-<$DATE.DAY>|<$TIME.HOUR>:<$TIME.MIN>:<$TIME.SEC>成功售出
SaveExVar $STR(S1) $STR(S0) 寄售上线提醒 ..\QuestDiary\数据文件\玄坛数据.txt
#IF
!EQUAL M0 $STR(P0)
small M0 $STR(P0)
#ACT
dec P0 $STR(M0)
GOTO @寄售排列1
break
[@寄售排列1]
#IF
LARGE P5 50
#ACT
$STR(S0).GAMEGOLD + $STR(P0)
Break
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S5 $STR(P5)
MOV P4 99999999999
#IF
!EQUAL S5
#ACT
GETVALIDSTR $STR(S5) | S6 S7
GETVALIDSTR $STR(S7) | P4 S6
#IF
SMALL P3 $STR(P4)
#ACT
FORMATSTR S4 %s|%s|{Color=yellow#32%-18s}%-10s%-12s%s <$STR(P0)>|<$STR(P3)>|<$STR(S0)>|<$STR(P0)>|<$STR(P3)>|{购买/@YuanBaoBuy2&<$STR(S0)>}
INSERTVARLIST $STR(P5) $STR(S4) ..\QuestDiary\无限排行\玄坛数据.txt
#ELSEACT
INC P5 1
GOTO @寄售排列1
Break
;========================================================================================
[@查询元宝]
#IF
random 1
#ACT
mov S1 0
#IF
PosInList $USERNAME ..\QuestDiary\无限排行\玄坛数据.txt S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
#IF
#SAY
欢迎回来，你目前在我这里寄售的元宝数量是<$STR(S1)>个。\
\
<离开/@exit>
[@取消寄售]
#IF
PosInList $USERNAME ..\QuestDiary\无限排行\玄坛数据.txt S0
#ACT
DELVARLIST $STR(S0) ..\QuestDiary\无限排行\玄坛数据.txt
GETVALIDSTR $STR(S0) | S1 S2
GAMEGOLD + $STR(S1)
#SAY
取消操作成功！\
\
<离开/@exit>
#ELSESAY
对不起，你并没有在我这里寄售元宝！\
\
<离开/@exit>
[@寄售元宝]
#IF
CHECKVAR HUMAN 寄售领取金币 > 0
#ACT
break
#SAY
请先领取了你的奖品或卖出元宝所得的金币后再来吧。\
\
<离开/@exit>
#IF
#SAY
注意事项：\
请输入你要寄售的元宝数量\\
<离开/@exit>
#ACT
QUERYVAL 0 1 3 @寄售的元宝数量 请输入你要寄售的元宝数量
break
[@寄售的元宝数量]
#IF
LARGE M0 0
#SAY
注意事项：\
请输入你要寄售元宝的<COLOR=GREEN 单价>（单位：万）\\
<离开/@exit>
#ACT
QUERYVAL 1 1 3 @购买的元宝数量 请输入你要寄售元宝的单价（单位：万）
break
[@购买的元宝数量]
请核对你输入的元宝数量和价格：\
元宝数量 {Color=yellow <$STR(M0)>}\
寄售元宝的{Color=green 单价} {Color=yellow <$STR(M1)>}万\\
<确认/@去热>　　<更正/@寄售元宝>　　<离开/@exit>
[@去热]
#IF
large M1 500
#ACT
break
#SAY
输入的单价数量不能大于500万，请重新输入。\
\
<离开/@exit>
#IF
PosInList $USERNAME ..\QuestDiary\无限排行\玄坛数据.txt S0
#SAY
你的元宝正在寄售中！\\
<离开/@exit>
#IF
CHECKGAMEGOLD / $STR(M0)
#ACT
GAMEGOLD - $STR(M0)
MULT M1 10000
mov P0
mov P2
goto @寄售排列
#SAY
你已经成功寄售了<$STR(M0)>个元宝，请常来关注元宝的寄售情况，如\
果在离线期间你所寄售的元宝成功售出，我们会通过系统短消\
息通知你。请上线后留意对话框中的红字提示。\
\
<离开/@exit>
#ELSESAY
很抱歉，你没有足够的元宝！\
\
<离开/@exit>
[@寄售排列]
#IF
PosInList $USERNAME ..\QuestDiary\无限排行\玄坛数据.txt S0
#ACT
DELVARLIST $STR(S0) ..\QuestDiary\无限排行\玄坛数据.txt
#IF
large P0 50
#ACT
GAMEGOLD + $STR(M0)
break
#SAY
允许寄售的位置已满，请稍后再试！\
\
<离开/@exit>
#IF
random 1
#ACT
ReadRandomStr ..\QuestDiary\无限排行\玄坛数据.txt S0 $STR(P0)
mov P1 99999999999
#IF
!equal S0
#ACT
GETVALIDSTR $STR(S0) | S1 S2
GETVALIDSTR $STR(S2) | P1 S3
#IF
small M1 $STR(P1)
#ACT
FORMATSTR S0 %s|%s|{Color=yellow#32%-18s}%-10s%-12s%s <$STR(M0)>|<$STR(M1)>|<$USERNAME>|<$STR(M0)>|<$STR(M1)>|{购买/@YuanBaoBuy2&<$USERNAME>}
INSERTVARLIST $STR(P0) $STR(S0) ..\QuestDiary\无限排行\玄坛数据.txt
#ELSEACT
inc P0 1
goto @寄售排列
break